VC-LTL/src/VC-LTL.cmd at master · pythonfansx/VC-LTL · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
@echo off

::自动生成VC-LTL库

::使用64位编译工具，提升性能
set PreferredToolArchitecture=x64

set Path=C:\Program Files (x86)\Microsoft Visual Studio\2019\Community\Common7\IDE;%Path%

::先生成静态库
call:Build Static "x86 x64 ARM ARM64"

call:Build Static_Spectre "x86 x64 ARM ARM64"

call:Build Static_WinXP "x86 x64"

call:Build Static_WinXP_Spectre "x86 x64"

::生成动态UCRT库
call:Build Redist "x86 x64 ARM ARM64" "ucrt\ucrt.vcxproj"
::call:Build Dynamic "x86 x64 ARM ARM64" "ucrt\ucrt.vcxproj"


::生成 CRT

call:BuildCRT 14.0.23918 "x86 x64 ARM"

call:BuildCRT 14.0.24210 "x86 x64 ARM"

call:BuildCRT 14.0.24225 "x86 x64 ARM"

call:BuildCRT 14.0.24231 "x86 x64 ARM"

call:BuildCRT 14.10.25017 "x86 x64 ARM ARM64"

call:BuildCRT 14.11.25503 "x86 x64 ARM ARM64"

call:BuildCRT 14.12.25827 "x86 x64 ARM ARM64"

call:BuildCRT 14.13.26128 "x86 x64 ARM ARM64"

call:BuildCRT 14.14.26428 "x86 x64 ARM ARM64"

call:BuildCRT 14.15.26726 "x86 x64 ARM ARM64"

call:BuildCRT 14.16.27023 "x86 x64 ARM ARM64"

call:BuildCRT 14.20.27508 "x86 x64 ARM ARM64"

call:BuildCRT 14.21.27702 "x86 x64 ARM ARM64"

call:BuildCRT 14.22.27905 "x86 x64 ARM ARM64"

call:BuildCRT 14.23.28105 "x86 x64 ARM ARM64"

::生成动态Spectre库
call:Build Dynamic_Spectre "x86 x64 ARM ARM64"

pause

goto:eof


::BuildCRT 14.0.24231 "x86 x64 ARM ARM64"
:BuildCRT

::生成msvcrt.lib
call:Build Dynamic %2 "%1\Build\ltlbuild\ltlbuild.vcxproj"

::生成msvcmrt.lib
call:Build Dynamic %2 "%1\Build\ltlbuild_CLR\ltlbuild_CLR.vcxproj"

::生成vcruntime.lib
call:Build Redist  %2 "%1\Build\vcruntime\vcruntime.vcxproj"

::生成msvcprt.lib
call:Build Redist  %2 "%1\Build\stl\stl.vcxproj"
call:Build Dynamic %2 "%1\Build\stl\stl.vcxproj"

::生成concrt.lib
call:Build Redist  %2 "%1\Build\ConcRT\ConcRT.vcxproj"

goto:eof


::Build Dynamic "x86 x64 ARM ARM64" ["ucrt\ucrt.vcxproj"]
:Build

for %%i in (%~2)do call:BuildWithErrorCheck "%1|%%i" %3

goto:eof

:BuildWithErrorCheck :: Dynamic|x86   ["ucrt\ucrt.vcxproj"]

if "%2"=="" ( devenv "%~dp0VC-LTL.sln" /Build %1 ) else ( devenv "%~dp0VC-LTL.sln" /Build %1 /project %2 )

if %ERRORLEVEL% NEQ 0 echo %1 %2 编译遇到问题，请查错后继续。&&pause

goto:eof